RON

Rete Ondametrica Nazionale

La Rete Ondametrica Nazionale (RON), è il sistema di rilevamento del moto ondoso dell’ISPRA, costituito da una rete di quindici stazioni di misura in punti fissi lungo le coste nazionali per la raccolta di dati che, opportunamente elaborati, caratterizzano lo stato del mare. I parametri descrittivi derivano dall’osservazione in continuo della variazione della superficie del mare attraverso boe ondametriche direzionali e vengono elaborati ad intervalli di tempo regolari secondo le definizioni della linea guida n.702 “Guide to wave analysis and forecasting” della World Meteorological Organization (WMO).

La pubblicazione del dataset RON sul portale Linked ISPRA, in tecnologia Linked Open Data, riguarderà inizialmente i quattro principali parametri sintetici atti a definire lo stato del mare, estratti dall’archivio della rete ondametrica per gli anni dal 2009 al 2014, nonché, due indicatori utili per la selezione di eventi notevoli. Successivamente, la pubblicazione verrà estesa a tutti i periodi disponibili e, progressivamente, ad altri parametri ed indici. Alla riattivazione della rete di monitoraggio, si provvederà alla distribuzione dei dati rilevati in tempo reale. Il livello di validazione di ciascun parametro rilasciato è definito nel relativo metadato.

Per approfondimenti:

Storia ed evoluzione della Rete Ondametrica Nazionale

reteondametrica@isprambiente.it

COSA CONTIENE?

  • Altezza d’onda significativa spettrale (Hm0);
  • Periodo medio dell’onda (Tm);
  • Periodo di picco dell’onda (Tp);
  • Direzione media di provenienza del moto ondoso (Dir);
  • Massimo mensile di altezza d’onda significativa (“indicatore”);
  • Direzione associata al massimo mensile dell’altezza d’onda significativa (“indicatore”).

query di esempio

[esegui query] – I dati di onda ad Alghero dal 2002 al 2010

PREFIX : <http://dati.isprambiente.it/ontology/core#>
PREFIX gn: <http://www.geonames.org/ontology#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dcat: <http://www.w3.org/ns/dcat#>
 
select distinct ?station ?period ?csvUrl where {

#### Definire Parametro, Luogo e Periodo
?parameter a :Wave.
?place rdfs:label "Alghero".
FILTER ( str(?period) >= '2002-01' AND str(?period) <= '2010-12').
 
?parameter gn:nearbyFeature ?place.
?collection a :MeasurementCollection;
:measurementPeriod ?period;
:isDataOf ?parameter;
:generatedBy ?instrument;
dcat:downloadURL ?csvUrl.
?instrument :placedOn ?stat.
?stat rdfs:label ?station.
} ORDER BY ?period

[esegui query] – I dati di onda del dataset RON ad Alghero dal 2002 al 2010

PREFIX : <http://dati.isprambiente.it/ontology/core#>
PREFIX gn: <http://www.geonames.org/ontology#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX purl: <http://purl.org/dc/terms/>
select distinct ?station ?period ?csvUrl where {

#### Definire Parametro, Luogo, Dataset e Periodo
?parameter a :Wave.
?place rdfs:label "Alghero".
?dataset rdfs:label "Dataset RON"@it.
FILTER ( str(?period) >= '2002-01' AND str(?period) <= '2010-12').
 
?parameter gn:nearbyFeature ?place.
?collection a :MeasurementCollection;
:measurementPeriod ?period;
:isDataOf ?parameter;
:generatedBy ?instrument;
purl:isPartOf ?dataset;
dcat:downloadURL ?csvUrl.
?instrument :placedOn ?stat.
?stat rdfs:label ?station.
} ORDER BY ?period

[esegui query] – I dati di onda della rete RON del 2009 ad Alghero

PREFIX : <http://dati.isprambiente.it/ontology/core#>
PREFIX gn: <http://www.geonames.org/ontology#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX purl: <http://purl.org/dc/terms/>
 
select distinct ?station ?period ?csvUrl where {
 
#### Definire Parametro, Luogo, Rete
?parameter a :Wave.
?place rdfs:label "Alghero".
?network rdfs:label "Rete Ondametrica Nazionale (2009-2014)".
 
?parameter gn:nearbyFeature ?place.
?collection a :MeasurementCollection;
:measurementPeriod ?period;
:isDataOf ?parameter;
:generatedBy ?instrument;
dcat:downloadURL ?csvUrl.
?instrument :placedOn ?stat.
?stat rdfs:label ?station.
?stat purl:isPartOf ?network.
} ORDER BY ?period

[esegui query] – I dati di onda nel mar Ionio tra il 2002 e il 2010

PREFIX : <http://dati.isprambiente.it/ontology/core#>
PREFIX gn: <http://www.geonames.org/ontology#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX purl: <http://purl.org/dc/terms/>
 
select distinct ?station ?period ?csvUrl where {

#### Definire Parametro, Mare e Periodo
?parameter a :Wave.
?sea rdfs:label "Mare Ionio".
FILTER ( str(?period) >= '2002-01' AND str(?period) <= '2010-12').
 

?collection a :MeasurementCollection;
:measurementPeriod ?period;
:isDataOf ?parameter;
:generatedBy ?instrument;
dcat:downloadURL ?csvUrl.
?instrument :placedOn ?stat.
?stat rdfs:label ?station.
?stat gn:locatedIn ?sea.
} ORDER BY ?period

[esegui query] – I dati di onda a Catania tra marzo e luglio 2010 con grafici

PREFIX : <http://dati.isprambiente.it/ontology/core#>
PREFIX dcterm: <http://purl.org/dc/terms/>
PREFIX gn: <http://www.geonames.org/ontology#>
PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>

select distinct ?period ?csvFile ?waveHeight ?waveRose ?waveDirection where {

?buoy a :MeasureStation; 
  :measures ?waves;
  gn:nearbyFeature ?place.
?collection a :MeasurementCollection;
  dcterm:isPartOf ?dataset;
  :measurementPeriod ?period;
  :isDataOf ?waves; 
  dcat:downloadURL ?csvFile.
?dataset dcterm:title 'Dataset RON'@it.

OPTIONAL {?collection foaf:depiction ?waveHeight . FILTER ( regex(str(?waveHeight), 'waveheight'))}.
OPTIONAL {?collection foaf:depiction ?waveRose . FILTER ( regex(str(?waveRose), 'waverose'))}.
OPTIONAL {?collection foaf:depiction ?waveDirection. FILTER ( regex(str(?waveDirection), 'wavedir'))}.

### Fill these lines to change measure station and measurement period ####
?place gn:name 'Catania'.
FILTER ( str(?period) >= '2010-03' AND str(?period) <= '2010-07').

} ORDER BY ?period

[esegui query] – I dati di onda a Catania a settembre 2010 con indicatori mensili

select distinct ?period ?csvUrl ?maxHm0 ?dirmaxHm0 where {

?buoy a <http://dati.isprambiente.it/ontology/core#MeasureStation>; 
<http://www.geonames.org/ontology#nearbyFeature> ?place.
?place <http://www.geonames.org/ontology#name> "Catania".
?collection a <http://dati.isprambiente.it/ontology/core#MeasurementCollection>;
<http://dati.isprambiente.it/ontology/core#measurementPeriod> ?period.
{?buoy <http://dati.isprambiente.it/ontology/core#measures> ?parameter. 
?collection <http://dati.isprambiente.it/ontology/core#isDataOf> ?parameter; 
<http://dati.isprambiente.it/ontology/core#isDataOf> ?cataniaWaves; 
<http://www.w3.org/ns/dcat#downloadURL> ?csvUrl}

FILTER ( str(?period) = '2010-09').

?maxIndicator1 a <http://dati.isprambiente.it/ontology/core#MarineIndicator>;
<http://purl.org/dc/terms/type> <http://dati.isprambiente.it/id/skos/marineindicator/montlymaxhm0>; 
<http://www.w3.org/1999/02/22-rdf-syntax-ns#value> ?maxHm0;
<http://purl.org/dc/terms/source> ?collection.
?maxIndicator2 a <http://dati.isprambiente.it/ontology/core#MarineIndicator>;
<http://purl.org/dc/terms/type> <http://dati.isprambiente.it/id/skos/marineindicator/montlymaxdir>; 
<http://www.w3.org/1999/02/22-rdf-syntax-ns#value> ?dirmaxHm0;
<http://purl.org/dc/terms/source> ?collection.
} ORDER BY ?period

[esegui query] – I dati di onda a Catania nel 2010 con Massimo mensile dell’altezza d’onda significativa superiore a 3 metri

select distinct ?period ?csvUrl ?maxHm0 ?dirmaxHm0 where {

?buoy a <http://dati.isprambiente.it/ontology/core#MeasureStation>; 
<http://www.geonames.org/ontology#nearbyFeature> ?place.
?place <http://www.geonames.org/ontology#name> "Catania".
?collection a <http://dati.isprambiente.it/ontology/core#MeasurementCollection>;
<http://dati.isprambiente.it/ontology/core#measurementPeriod> ?period.
{?buoy <http://dati.isprambiente.it/ontology/core#measures> ?parameter. 
?collection <http://dati.isprambiente.it/ontology/core#isDataOf> ?parameter; 
<http://dati.isprambiente.it/ontology/core#isDataOf> ?cataniaWaves; 
<http://www.w3.org/ns/dcat#downloadURL> ?csvUrl}

?maxIndicator1 a <http://dati.isprambiente.it/ontology/core#MarineIndicator>;
<http://purl.org/dc/terms/type> <http://dati.isprambiente.it/id/skos/marineindicator/montlymaxhm0>; 
<http://www.w3.org/1999/02/22-rdf-syntax-ns#value> ?maxHm0;
<http://purl.org/dc/terms/source> ?collection.
?maxIndicator2 a <http://dati.isprambiente.it/ontology/core#MarineIndicator>;
<http://purl.org/dc/terms/type> <http://dati.isprambiente.it/id/skos/marineindicator/montlymaxdir>; 
<http://www.w3.org/1999/02/22-rdf-syntax-ns#value> ?dirmaxHm0;
<http://purl.org/dc/terms/source> ?collection.

FILTER ( str(?period) >= '2010-01' AND str(?period) <= '2010-12' AND str(?maxHm0) > '3').

} ORDER BY ?period

 

[esegui query] – I dati RON del Mar Ionio

select distinct ?station ?type ?period ?buoy ?parameter ?csvUrl where {

?buoy a <http://dati.isprambiente.it/ontology/core#MeasureStation>;
<http://purl.org/dc/terms/isPartOf> <http://dati.isprambiente.it/id/buoy/ron/ron-09>;
<http://www.w3.org/2000/01/rdf-schema#label> ?station;
<http://www.geonames.org/ontology#locatedIn> ?mare.
?mare <http://www.w3.org/2000/01/rdf-schema#label> "Mare Ionio".

?instrument <http://www.w3.org/1999/02/22-rdf-syntax-ns#type> ?typeinstr.
?typeinstr <http://www.w3.org/2000/01/rdf-schema#subClassOf> <http://dati.isprambiente.it/ontology/core#Instrument>.
?instrument <http://dati.isprambiente.it/ontology/core#placedOn> ?buoy.

?collection a <http://dati.isprambiente.it/ontology/core#MeasurementCollection>;
<http://dati.isprambiente.it/ontology/core#measurementPeriod> ?period;
<http://dati.isprambiente.it/ontology/core#isDataOf> ?parameter;
<http://dati.isprambiente.it/ontology/core#generatedBy> ?instrument;
<http://www.w3.org/ns/dcat#downloadURL> ?csvUrl.
?parameter <http://www.w3.org/2000/01/rdf-schema#label> ?type.
} ORDER BY ?period

[esegui query] – Stazioni RON e RMN del Mar Adriatico

select distinct ?station ?uri ?network where {

?uri a <http://dati.isprambiente.it/ontology/core#MeasureStation>;
<http://www.w3.org/2000/01/rdf-schema#label> ?station;
<http://purl.org/dc/terms/isPartOf> ?neturi;
<http://www.geonames.org/ontology#locatedIn> ?mare.
?mare <http://www.w3.org/2000/01/rdf-schema#label> 'Mare Adriatico'.
?neturi <http://www.w3.org/2000/01/rdf-schema#label> ?network.
} ORDER BY ?network ?station


ron