RMN

La Rete Mareografica Nazionale

La Rete Mareografica Nazionale (RMN) è composta di 36 stazioni di misura uniformemente distribuite sul territorio nazionale ed ubicate prevalentemente all’interno delle strutture portuali.
Tutte le stazioni sono dotate di un sistema locale di gestione e memorizzazione dei dati e di un apparato di trasmissione (UMTS) in tempo reale alla sede centrale ISPRA di Roma. Inoltre in 9 stazioni strategiche per la misura di fenomeni particolari (onde anomale) è presente un secondo sistema di trasmissione dati via satellite con tecnologia IRIDIUM che garantisce il collegamento anche in presenza di situazioni di black-out del sistema UMTS.
Da quando la nuova Rete Mareografica Nazionale è pienamente operativa, ISPRA mette a disposizione degli utenti informazioni aggiornate relative a serie storiche, osservazioni in tempo reale, previsione dei dati di marea astronomica, analisi dei dati a fini progettuali e scientifici.

La pubblicazione del dataset RMN sul portale Linked ISPRA consentirà la distribuzione, in tecnologia Linked Open Data, dei dati rilevati in tempo reale.

Per approfondimenti:

retemareografica@isprambiente.it

COSA CONTIENE?
  • Livello del mare (metri);
  • Temperatura dell’acqua (gradi C);
  • Temperatura dell’aria (gradi C);
  • Umidità (%);
  • Pressione atmosferica (hPa);
  • Direzione vento (gradi N);
  • Velocità vento (m/s).

QUERY DI ESEMPIO

[esegui query] – Dati sulla pressione dell’aria nel Mare Adriatico

PREFIX ispra-top: <https://w3id.org/italia/env/onto/top/>
PREFIX ispra-emf: <https://w3id.org/italia/env/onto/inspire-mf/>
PREFIX ispra-plc: <https://w3id.org/italia/env/onto/place/>

SELECT DISTINCT ?dataset ?station str(?ym) as ?YearMonth ?url
WHERE
{
# Define Parameter and Sea
?obs a ispra-emf:ObservationSeries;
  ispra-emf:isObservationMadeBySensor ?sen;
  ispra-emf:hasObservationParameter ?obp;
  ispra-top:atTime ?tim;
  ispra-top:isPartOf ?col1;
  ispra-top:hasMedia ?med.

?col1   ispra-top:isPartOf ?col2.
?col2   ispra-top:isPartOf ?dts.

?dts rdfs:label ?dataset.

?med ispra-top:hasDownloadURL ?url.
?sen ispra-emf:isHostedBy ?plt.

# Parameter
?obp rdfs:label "AirPressure".

?plt  ispra-top:name ?station;
ispra-plc:hasFeature ?foi.

?foi ispra-top:isPartOf ?sea.

# Sea
?sea rdfs:label "Adriatic Sea"@en.

?tim ispra-top:time ?ym.
FILTER (?ym >= "2022-01"^^xsd:gYearMonth && ?ym <= "2022-03"^^xsd:gYearMonth)
} ORDER by ?dataset ?ym ?station

[esegui query] – Le Stazioni delle reti RON, RMN e RMLV

PREFIX ispra-top: <https://w3id.org/italia/env/onto/top/>
PREFIX ispra-emf: <https://w3id.org/italia/env/onto/inspire-mf/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>

SELECT DISTINCT
str(?network) AS ?network str(?statname) AS ?statname ?stat ?lat ?long
WHERE {
?stat a ispra-emf:Platform;
  ispra-top:name ?statname ;
  geo:lat ?lat;
  geo:long ?long;
  ispra-emf:isPlatformOf / rdfs:label ?network .
FILTER (langMatches(lang(?network), "en"))
}
ORDER BY ?network ?statname

[esegui query] – I dati a Civitavecchia dal 2009 al 2022

PREFIX ispra-top: <https://w3id.org/italia/env/onto/top/>
PREFIX ispra-emf: <https://w3id.org/italia/env/onto/inspire-mf/>

SELECT DISTINCT
str(?station) AS ?station
?starttime
?endtime
str(?labelpar) as ?descparameter
?csvUrl
WHERE
{
#### You can define Parameter, Place and Period
#CSV RMN Columns: "BAR" = "Air pressure", "AT" = "Air temperature", "Level" = "Hydrometric level", "RH" = "Relative humidity", ("WS" = "Wind speed", "WD" = "Wind direction"), "WT" = "Water temperature"
#FILTER(str(?labelpar) = "AirPressure" OR str(?labelpar) = "AirTemperature" OR str(?labelpar) = "HydrometricLevel" OR str(?labelpar) = "RelativeHumidity" OR str(?labelpar) = "Wind" OR str(?labelpar) = "WaterTemperature")

#CSV RON Columns: "airPres" = "Air pressure", ("Hm0" = "Significant wave height", "Dir" = "Mean direction from which waves are coming", "Tm" = "Average wave period", "Tp" = "Spectral peak wave period"), "rh" = "Relative humidity", ("Vv" = "Wind speed", "Dv" = "Wind direction")
#FILTER(str(?labelpar) = "AirPressure" OR str(?labelpar) = "Wave" OR str(?labelpar) = "RelativeHumidity" OR str(?labelpar) = "Wind")

FILTER(str(?placelabel) = "Civitavecchia")
FILTER (?starttime >= "2009-01-01T00:00:00Z"^^xsd:dateTime && ?endtime <= "2022-12-31T23:59:59Z"^^xsd:dateTime)
GRAPH <https://w3id.org/italia/env/ld/rmn/>
#GRAPH <https://w3id.org/italia/env/ld/ron/>
#GRAPH <https://w3id.org/italia/env/ld/rmlv/>
{
?obseries ispra-emf:hasObservationParameter ?parameter;
  ispra-top:atTime ?timeinterval;
  ispra-top:isPartOf ?obscolltop;
  ispra-emf:isObservationMadeBySensor ?instrument;
  ispra-top:hasMedia ?media .
?timeinterval ispra-top:startTime ?starttime;
  ispra-top:endTime ?endtime .
?parameter rdfs:label ?labelpar .
?instrument ispra-emf:isHostedBy ?stat .
?stat rdfs:label ?station .
?media ispra-top:hasDownloadURL ?csvUrl .
?obscolltop ispra-top:isPartOf ?coll .
?coll ispra-top:isPartOf <https://w3id.org/italia/env/ld/rmn/dataset>;
#?coll ispra-top:isPartOf <https://w3id.org/italia/env/ld/ron/dataset>;
#?coll ispra-top:isPartOf <https://w3id.org/italia/env/ld/rmlv/dataset>;
  ispra-top:isCollectionOf ?place .
}
?place rdfs:label ?placelabel.
FILTER (langMatches(lang(?placelabel),"it"))
FILTER (langMatches(lang(?station),"it"))
}
ORDER BY ?csvUrl

ron