Consumo di suolo

Il consumo di suolo in Italia

Il quadro conoscitivo sul consumo di suolo nel nostro Paese è disponibile grazie ai dati delle mappe nazionali del consumo di suolo, realizzate da ISPRA con la collaborazione delle Agenzie per la Protezione dell’Ambiente delle Regioni e delle Province autonome. Il sistema permette, attualmente, di ricostruire l’andamento del consumo di suolo in Italia dal 2012 ad oggi.

Il monitoraggio nazionale del consumo di suolo garantisce infatti la disponibilità di mappe tematiche ad elevata accuratezza e stime quantitative dell’intero territorio; potrebbe essere integrato con altre fonti cartografiche ad elevata risoluzione per derivare molteplici indicatori.

La carta nazionale del consumo di suolo di ISPRA può assicurare il monitoraggio del consumo di suolo anche su scala locale (es. comunale). Le mappe del consumo di suolo con risoluzione di 10 m sono disponibili per il 2012 e sono prodotte annualmente dal 2015. Questi dati, e gli indicatori da essi derivati, sono pubblicati qui in RDF ed in formato tabellare su SINANET.

Questa indagine viene attualmente integrata con altre cartografie, necessarie sia per garantirne la validazione, sia per assicurare una maggiore e più coerente spazializzazione dei dati, partecipando direttamente e attivamente, in particolare, all’iniziativa Copernicus che ha permesso di ottenere, negli ultimi anni, delle cartografie estremamente più dettagliate del Corine Land Cover, precedentemente utilizzato.

Le mappe e i relativi indicatori rappresentano il riferimento ufficiale a livello nazionale per le informazioni statistiche derivanti dal monitoraggio del consumo di suolo. L’indagine ISPRA rappresenta la più significativa collezione di dati a livello nazionale che ricostruisce l’andamento del consumo di suolo in Italia dagli anni ’50 ad oggi. La metodologia di rilevazione sviluppata, l’unica dedicata specificamente al tema del consumo di suolo, è in grado di integrare le diverse fonti di dati con dati di osservazione della terra a livello europeo, utilizzando analisi cartografiche e aero-fotogrammetriche.

Per approfondimenti:

Sezione dedicata al consumo di suolo

Il rapporto sul consumo di suolo in Italia

consumosuolo@isprambiente.it

COSA CONTIENE?
  • Per ogni luogo (regione/provincia/comune) collezione di indicatori di consumo del suolo associati all’anno di riferimento
  • Ogni particolare indicatore è definito nel vocabolario consumo suolo (in formato SKOS)

QUERY DI ESEMPIO

[esegui query] – I primi 100 comuni per percentuale di consumo di suolo nel 2021 (indicatore CSUOLO4)

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX ispra-top: <https://w3id.org/italia/env/onto/top/>   
PREFIX ispra-plc: <https://w3id.org/italia/env/onto/place/>     
PREFIX ispra-emf: <https://w3id.org/italia/env/onto/inspire-mf/>   
PREFIX dsw: <http://purl.org/dsw/>
PREFIX dwc: <http://rs.tdwg.org/dwc/terms/>
PREFIX dwciri: <http://rs.tdwg.org/dwc/iri/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT DISTINCT  (SUBSTR(str(?year), 1, 4) AS ?anno) (str(?mundesc) AS ?comune) (str(?provdesc) AS ?provincia)  (str(?value) AS ?percentuale) ?URI
WHERE
{
### Define data interval and indicator
FILTER (?year = "2021"^^xsd:gYear)
?par ispra-top:identifier "soilc_CSUOLO4" .
###
FILTER (langMatches(lang(?indicator),"en"))
?mun a ispra-plc:Municipality;  
  rdfs:label ?mundesc;
  ispra-plc:istat ?lau_com;
  ispra-plc:hasDirectHigherRank ?prov .
?prov rdfs:label ?provdesc.
?c a ispra-top:Collection;
  ispra-top:isPartOf <https://w3id.org/italia/env/ld/soilc/dataset>;
  ispra-top:isCollectionOf ?mun .    
?ic a ispra-emf:IndicatorCollection;
  ispra-top:isPartOf ?c.
?icc a ispra-emf:IndicatorCollection;
  ispra-top:isPartOf ?ic;
  ispra-top:isParametrisedBy ?par .
?URI a ispra-emf:Indicator;
  rdfs:label ?indicator;
  ispra-top:isMemberOf ?icc;
  ispra-top:atTime ?yy;
  ispra-top:hasValue ?vv.
?yy ispra-top:year ?year.  
?vv ispra-top:value ?value.
}
ORDER by DESC(xsd:float(?value) ) LIMIT 100


[esegui query] – Le prime 10 province per percentuale di consumo di suolo nel 2021 (indicatore CSUOLO4)

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX ispra-top: <https://w3id.org/italia/env/onto/top/>   
PREFIX ispra-plc: <https://w3id.org/italia/env/onto/place/>     
PREFIX ispra-emf: <https://w3id.org/italia/env/onto/inspire-mf/>   
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX clvapit: <https://w3id.org/italia/onto/CLV/>

SELECT DISTINCT  (SUBSTR(str(?year), 1, 4) AS ?anno)  (str(?provdesc) AS ?provincia)  (str(?value) AS ?percentuale) ?URI
WHERE
{
### Define data interval and indicator
FILTER (?year = "2021"^^xsd:gYear)
?par ispra-top:identifier "soilc_CSUOLO4" .
###
FILTER (langMatches(lang(?indicator),"en"))
?prov rdfs:label ?provdesc;
  clvapit:hasRankOrder "3" .
?c a ispra-top:Collection;
  ispra-top:isPartOf <https://w3id.org/italia/env/ld/soilc/dataset>;
  ispra-top:isCollectionOf ?prov.    
?ic a ispra-emf:IndicatorCollection;
  ispra-top:isPartOf ?c.
?icc a ispra-emf:IndicatorCollection;
  ispra-top:isPartOf ?ic;
  ispra-top:isParametrisedBy ?par .
?URI a ispra-emf:Indicator;
  rdfs:label ?indicator;
  ispra-top:isMemberOf ?icc;
  ispra-top:atTime ?yy;
  ispra-top:hasValue ?vv.
?yy ispra-top:year ?year.  
?vv ispra-top:value ?value.
}
ORDER by DESC(xsd:float(?value) ) LIMIT 10


[esegui query] – Le regioni (tutte) per percentuale di consumo di suolo nel 2021 (indicatore CSUOLO4)

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX ispra-top: <https://w3id.org/italia/env/onto/top/>   
PREFIX ispra-plc: <https://w3id.org/italia/env/onto/place/>     
PREFIX ispra-emf: <https://w3id.org/italia/env/onto/inspire-mf/>   
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX clvapit: <https://w3id.org/italia/onto/CLV/>

SELECT DISTINCT  (SUBSTR(str(?year), 1, 4) AS ?anno)  (str(?regdesc) AS ?regione)  (str(?value) AS ?percentuale) ?URI
WHERE
{
### Define data interval and indicator
FILTER (?year = "2021"^^xsd:gYear)
?par ispra-top:identifier "soilc_CSUOLO4" .
###
FILTER (langMatches(lang(?indicator),"en"))
?reg rdfs:label ?regdesc;
  a ispra-plc:Region;
  clvapit:hasRankOrder "2" .
?c a ispra-top:Collection;
  ispra-top:isPartOf <https://w3id.org/italia/env/ld/soilc/dataset>;
  ispra-top:isCollectionOf ?reg.    
?ic a ispra-emf:IndicatorCollection;
  ispra-top:isPartOf ?c.
?icc a ispra-emf:IndicatorCollection;
  ispra-top:isPartOf ?ic;
  ispra-top:isParametrisedBy ?par .
?URI a ispra-emf:Indicator;
  rdfs:label ?indicator;
  ispra-top:isMemberOf ?icc;
  ispra-top:atTime ?yy;
  ispra-top:hasValue ?vv.
?yy ispra-top:year ?year.  
?vv ispra-top:value ?value.
}
ORDER by DESC(xsd:float(?value))


[esegui query] – I primi 100 comuni per ettari di consumo di suolo nel 2021 (indicatore CSUOLO1)

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX ispra-top: <https://w3id.org/italia/env/onto/top/>   
PREFIX ispra-plc: <https://w3id.org/italia/env/onto/place/>     
PREFIX ispra-emf: <https://w3id.org/italia/env/onto/inspire-mf/>   
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT  (SUBSTR(str(?year), 1, 4) AS ?anno) (str(?mundesc) AS ?comune) (str(?provdesc) AS ?provincia)  (str(?value) AS ?valore) (str(?umdesc) AS ?unitadimisura) ?URI 
WHERE
{
### Define data interval and indicator
FILTER (?year = "2021"^^xsd:gYear)
?par ispra-top:identifier "soilc_CSUOLO1" .
###
FILTER (langMatches(lang(?mundesc), "it"))
##FILTER (langMatches(lang(?provdesc), "it"))
FILTER (langMatches(lang(?umdesc), "it"))
##FILTER (langMatches(lang(?indicator), "it"))
?mun a ispra-plc:Municipality;  
  rdfs:label ?mundesc;
  ispra-plc:istat ?lau_com;
  ispra-plc:hasDirectHigherRank ?prov .
?prov rdfs:label ?provdesc.
?c a ispra-top:Collection;
  ispra-top:isPartOf <https://w3id.org/italia/env/ld/soilc/dataset>;
  ispra-top:isCollectionOf ?mun .    
?ic a ispra-emf:IndicatorCollection;
  ispra-top:isPartOf ?c.
?icc a ispra-emf:IndicatorCollection;
  ispra-top:isPartOf ?ic;
  ispra-top:isParametrisedBy ?par .
?URI a ispra-emf:Indicator;
  rdfs:label ?indicator;
  ispra-top:isMemberOf ?icc;
  ispra-top:atTime ?yy;
  ispra-top:hasValue ?vv.
?yy ispra-top:year ?year.  
?vv ispra-top:value ?value;
    ispra-top:hasUnitOfMeasure ?um.
?um rdfs:label ?umdesc
}
ORDER by DESC(xsd:float(?value) ) LIMIT 100


[esegui query] – Le prime 10 province per ettari di consumo di suolo nel 2021 (indicatore CSUOLO1)

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX ispra-top: <https://w3id.org/italia/env/onto/top/>   
PREFIX ispra-plc: <https://w3id.org/italia/env/onto/place/>     
PREFIX ispra-emf: <https://w3id.org/italia/env/onto/inspire-mf/>   
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX clvapit: <https://w3id.org/italia/onto/CLV/>

SELECT DISTINCT (SUBSTR(str(?year), 1, 4) AS ?anno) (str(?provdesc) AS ?provincia) (str(?value) AS ?valore) (str(?umdesc) AS ?unitadimisura) ?URI
WHERE
{
### Define data interval and indicator
FILTER (?year = "2021"^^xsd:gYear)
?par ispra-top:identifier "soilc_CSUOLO1" .
###
##FILTER (langMatches(lang(?provdesc), "it"))
FILTER (langMatches(lang(?umdesc), "it"))
##FILTER (langMatches(lang(?indicator), "it"))
?prov rdfs:label ?provdesc;
  clvapit:hasRankOrder "3" .
?c a ispra-top:Collection;
  ispra-top:isPartOf <https://w3id.org/italia/env/ld/soilc/dataset>;
  ispra-top:isCollectionOf ?prov.    
?ic a ispra-emf:IndicatorCollection;
  ispra-top:isPartOf ?c.
?icc a ispra-emf:IndicatorCollection;
  ispra-top:isPartOf ?ic;
  ispra-top:isParametrisedBy ?par .
?URI a ispra-emf:Indicator;
  rdfs:label ?indicator;
  ispra-top:isMemberOf ?icc;
  ispra-top:atTime ?yy;
  ispra-top:hasValue ?vv.
?yy ispra-top:year ?year.  
?vv ispra-top:value ?value;
    ispra-top:hasUnitOfMeasure ?um.
?um rdfs:label ?umdesc
}
ORDER by DESC(xsd:float(?value) ) LIMIT 10


[esegui query] – Le regioni (tutte) per ettari di consumo di suolo nel 2021 (indicatore CSUOLO1)

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX ispra-top: <https://w3id.org/italia/env/onto/top/>   
PREFIX ispra-plc: <https://w3id.org/italia/env/onto/place/>     
PREFIX ispra-emf: <https://w3id.org/italia/env/onto/inspire-mf/>   
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX clvapit: <https://w3id.org/italia/onto/CLV/>

SELECT DISTINCT  (SUBSTR(str(?year), 1, 4) AS ?anno)  (str(?regdesc) AS ?regione)  (str(?value) AS ?valore) (str(?umdesc) AS ?unitadimisura) ?URI
WHERE
{
### Define data interval and indicator
FILTER (?year = "2021"^^xsd:gYear)
?par ispra-top:identifier "soilc_CSUOLO1" .
###
##FILTER (langMatches(lang(?provdesc), "it"))
FILTER (langMatches(lang(?umdesc), "it"))
##FILTER (langMatches(lang(?indicator), "it"))
?reg rdfs:label ?regdesc;
  a ispra-plc:Region;
  clvapit:hasRankOrder "2" .
?c a ispra-top:Collection;
  ispra-top:isPartOf <https://w3id.org/italia/env/ld/soilc/dataset>;
  ispra-top:isCollectionOf ?reg.    
?ic a ispra-emf:IndicatorCollection;
  ispra-top:isPartOf ?c.
?icc a ispra-emf:IndicatorCollection;
  ispra-top:isPartOf ?ic;
  ispra-top:isParametrisedBy ?par .
?URI a ispra-emf:Indicator;
  rdfs:label ?indicator;
  ispra-top:isMemberOf ?icc;
  ispra-top:atTime ?yy;
  ispra-top:hasValue ?vv.
?yy ispra-top:year ?year.  
?vv ispra-top:value ?value;
    ispra-top:hasUnitOfMeasure ?um.
?um rdfs:label ?umdesc
}
ORDER by DESC(xsd:float(?value))

cds