Pesticidi

I Pesticidi in Italia

I pesticidi, da un punto di vista normativo, comprendono i prodotti fitosanitari (Reg. CE 1107/2009), utilizzati per la protezione delle piante e per la conservazione dei prodotti vegetali, e i biocidi (Reg. UE 528/2012), impiegati in vari campi di attività (disinfettanti, preservanti, pesticidi per uso non agricolo, ecc.). Spesso i due tipi di prodotti utilizzano gli stessi principi attivi.

Le Regioni e le Province Autonome realizzano il monitoraggio nell’ambito dei programmi di rilevazione previsti dal decreto legislativo 3 aprile 2006, n° 152 [D. Lgs. 152/2006], trasmettono i risultati all’ISPRA, che li elabora e valuta. L’ISPRA fornisce gli indirizzi tecnico scientifici per la programmazione del monitoraggio. L’Istituto, inoltre, alimenta alcuni degli indicatori previsti dal Piano d’Azione Nazionale per l’uso sostenibile dei prodotti fitosanitari (PAN), stabilito con il decreto 15 luglio 2015 [DM 172/2015]

Le concentrazioni dei residui di pesticidi sono confrontate con i limiti nelle acque stabiliti a livello
europeo e nazionale, definiti Standard di Qualità Ambientale (SQA). Per standard di qualità ambientale, come specificato nella Direttiva Quadro Acque (DQA -Direttiva 2000/60/CE), si intende “la concentrazione di un particolare inquinante o gruppo di inquinanti nelle acque, nei sedimenti e nel biota che non deve essere superata, per tutelare la salute umana e l’ambiente”.
Gli standard di qualità ambientale si basano sui livelli di tossicità di tipo acuto e cronico per le specie
rappresentative dell’ambiente acquatico.

La Direttiva 2006/118/CE sulla protezione delle acque sotterranee stabilisce norme di qualità ambientale, definiti come la concentrazione di un determinato inquinante, gruppo di inquinanti o indicatore di inquinamento nelle acque sotterranee che
non dovrebbe essere superata al fine di proteggere la salute umana e l’ambiente.

Per approfondimenti:

Portale dei pesticidi

Il rapporto pesticidi nelle acque in Italia

COSA CONTIENE?

• Anagrafica delle stazioni di monitoraggio e ai livelli di contaminazione, ottenuti dal confronto con i limiti di legge (Standard di qualità ambientale, SQA)
• Per ogni punto di monitoraggio è possibile consultare le informazioni geografiche, il livello di contaminazione, i pesticidi cercati e trovati e i dati statistici sul monitoraggio.

QUERY DI ESEMPIO

[esegui query] – Stazioni di acque superficiali nella regione Marche anno 2018 con livello di contaminazione superiore ai limiti

PREFIX ispra-top: <https://w3id.org/italia/env/onto/top/>
PREFIX ispra-plc: <https://w3id.org/italia/env/onto/place/>
PREFIX ispra-emf: <https://w3id.org/italia/env/onto/inspire-mf/>

SELECT DISTINCT
str(?geoyear) AS ?anno
str(?admincode) AS ?codiceamm
str(?codereg) AS ?codicereg
str(?regdesc) AS ?regione
str(?codeprov) AS ?codiceprov
str(?provdesc) AS ?provincia
str(?mundesc) AS ?comune
?platformtype AS ?tipopiattaforma
?long
?lat
?URIpiattaforma
?par AS ?URIparametro
str(?parlabel) AS ?parametro
?descvalue AS ?descvalore
WHERE
{
## IMPOSTARE CODICE REGIONE: ES. "11" = region code "Marche"
FILTER(str(?codereg)  = "11")
##TOGLIERE "#" DALLA RIGA SOTTO SE SI DESIDERA SELEZIONARE PER CODICE PROVINCIA (ES. "021" o "022" PER LE PROVINCE DI "Bolzano" o "Trento") ANTEPONENDO  "#" ALLA RIGA SOPRA
#FILTER(str(?codeprov)  = "021")

##PER ACQUE SOTTERRANEE SOSTITUIRE NELLA RIGA SOTTO pest_swcontlev CON pest_gwcontlev
?par ispra-top:identifier "pest_swcontlev" .
##PER ACQUE SOTTERRANEE SOSTITUIRE NELLA RIGA SOTTO sw CON gw
FILTER(?platformtype= "sw")
## SOSTITUIRE NELLA RIGA SOTTO L'ANNO (2018) CON QUELLO DESIDERATO
?time ispra-top:year "2018"^^xsd:gYear .
##TOGLIERE "#" DALLA RIGA SOTTO SE SI DESIDERA SELEZIONARE PER CODICE COMUNE (ES. "041033" O IMPOSTARE UN ALTRO CODICE)
#?mun ispra-plc:istat "041033"^^xsd:string .
## SOSTITUIRE NELLA RIGA SOTTO L'ANNO (2018) CON QUELLO DESIDERATO
?indicator ispra-top:hasSource /  ispra-plc:hasFeature ?geofeature ;
  ispra-top:isMemberOf ?icc;
  ispra-top:hasValue / ispra-top:value ?value .
?samplingseries a ispra-emf:SamplingSeries;
   ispra-plc:hasFeature ?geofeature .
?geofeature ispra-top:atTime ?time;
   geo:lat ?lat;
   geo:long ?long .
?c ispra-top:isPartOf <https://w3id.org/italia/env/ld/pest/dataset>;
  ispra-top:isCollectionOf ?mun .
?ic a ispra-emf:IndicatorCollection;
  ispra-top:isPartOf ?c.
?icc ispra-top:isPartOf ?ic;
  ispra-top:isParametrisedBy ?par .
?par rdfs:label ?parlabel .
?mun a ispra-plc:Municipality;
  rdfs:label ?mundesc;
  ispra-plc:istat ?lau_com;
  ispra-plc:hasDirectHigherRank ?prov ;
  ispra-plc:hasRegion ?reg .
?prov rdfs:label ?provdesc .
?prov ispra-plc:istat ?codeprov .
?reg rdfs:label ?regdesc.
?reg ispra-plc:istat ?codereg .
?time ispra-top:year ?geoyear .

BIND(IF(str(?value) = "0", "Non quantificabile", IF(str(?value) = "1", "Entro i limiti", IF(str(?value) = "2", "Superiore ai limiti","xxx"))) AS ?descvalue)
BIND(SUBSTR(str(?geofeature), 52, STRLEN(str(?geofeature)) - 56) AS ?platformidentifier)
BIND(SUBSTR(?platformidentifier, 1, 2) AS ?admincode)
BIND(SUBSTR(?platformidentifier, 3, 2) AS ?platformtype)
BIND(URI(CONCAT("https://w3id.org/italia/env/ld/pest/platform/00106_", ?platformidentifier, "_", str(?geoyear))) AS ?URIpiattaforma)
#FILTER(?admincode  = "11")
FILTER (langMatches(lang(?mundesc),"it"))
FILTER (langMatches(lang(?parlabel),"it"))
}
ORDER BY ?regdesc ?provdesc ?mundesc ?descvalue

[esegui query] – Stazioni di acque sotterranee nella regione Marche anno 2018 con livello di contaminazione, sostanze cercate, sostanze trovate, etc.

PREFIX ispra-top: <https://w3id.org/italia/env/onto/top/>
PREFIX ispra-plc: <https://w3id.org/italia/env/onto/place/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>

SELECT DISTINCT
str(?geoyear) AS ?anno
str(?regdesc) AS ?regione
str(?provdesc) AS ?provincia
str(?mundesc) AS ?comune
str(?lblbasin) AS ?bacino
?platformtype AS ?tipopiattaforma
?platformidentifier AS ?piattaforma
?lat
?long
?paridentifier AS ?codiceparametro
str(?parlabel) AS ?parametro
?valore
#str(?umdesc) AS ?unitadimisura
?URIpiattaforma
?par AS ?URIparametro
?indicator AS ?URIindicatore
WHERE
{
##TOGLIERE "#" DALLA RIGA SOTTO SE SI DESIDERA SELEZIONARE PER CODICE  REGIONE: ES. "11" = region code "Marche"
FILTER(str(?codereg)  = "11")
##TOGLIERE "#" DALLA RIGA SOTTO SE SI DESIDERA SELEZIONARE PER CODICE PROVINCIA (ES. "021" o "022" PER LE PROVINCE DI "Bolzano" o "Trento") ANTEPONENDO  "#" ALLA RIGA SOPRA
#FILTER(str(?codeprov)  = "021")

##PER ACQUE SUPERFICIALI SOSTITUIRE NELLA RIGA SOTTO gw CON sw
FILTER(?platformtype = "gw")

##TOGLIERE "#" DALLA RIGA SOTTO SE SI DESIDERA SELEZIONARE PER CODICE COMUNE (ES. "041033" O IMPOSTARE UN ALTRO CODICE)
#?mun ispra-plc:istat "041033"^^xsd:string .

## SOSTITUIRE NELLA RIGA SOTTO L'ANNO (2018) CON QUELLO DESIDERATO
?time ispra-top:year "2018"^^xsd:gYear .
## SOSTITUIRE NELLA RIGA SOTTO L'ANNO (2018) CON QUELLO DESIDERATO
?indicator ispra-top:hasSource / ispra-plc:hasFeature ?geofeature ;
  ispra-top:isMemberOf ?icc;
  ispra-top:hasValue / ispra-top:value ?value .
#ispra-top:hasUnitOfMeasure ?um.
?samplingseries ispra-plc:hasFeature ?geofeature .
?geofeature ispra-top:atTime ?time;
    geo:lat ?lat;
    geo:long ?long;
    ispra-top:isPartOf ?basin .
##PER ACQUE SUPERFICIALI SOSTITUIRE NELLA RIGA SOTTO pest_ggw CON pest_gsw
?parbroader ispra-top:identifier "pest_ggw" .

?c  ispra-top:isPartOf <https://w3id.org/italia/env/ld/pest/dataset>;
  ispra-top:isCollectionOf ?mun .
?ic  ispra-top:isPartOf ?c.
?icc  ispra-top:isPartOf ?ic;
  ispra-top:isParametrisedBy ?par .
?par rdfs:label ?parlabel;
  ispra-top:identifier ?paridentifier;
  ispra-top:hasBroader ?parbroader .
#?um rdfs:label ?umdesc .
?mun  rdfs:label ?mundesc;
  ispra-plc:istat ?lau_com;
  ispra-plc:hasDirectHigherRank ?prov ;
  ispra-plc:hasRegion ?reg .
?prov rdfs:label ?provdesc .
?prov ispra-plc:istat ?codeprov .
?reg rdfs:label ?regdesc.
?reg ispra-plc:istat ?codereg .
#?codereg bif:contains "'11'".
#FILTER ( isLiteral(?codereg ) ) .
?time ispra-top:year ?geoyear .
?basin rdfs:label ?lblbasin .

FILTER (langMatches(lang(?mundesc),"it"))
FILTER (langMatches(lang(?parlabel),"it"))
#FILTER(lang(?umdesc)='it')
FILTER(lang(?lblbasin)='it')
BIND(SUBSTR(str(?geofeature), 52, STRLEN(str(?geofeature)) - 56) AS ?platformidentifier)
BIND(SUBSTR(?platformidentifier, 1, 2) AS ?admincode)
BIND(SUBSTR(?platformidentifier, 3, 2) AS ?platformtype)
BIND(URI(CONCAT("https://w3id.org/italia/env/ld/pest/platform/00106_", ?platformidentifier, "_", str(?geoyear))) AS ?URIpiattaforma)
BIND(IF(str(?value) = "0" && (?paridentifier = "pest_swcontlev" || ?paridentifier = "pest_gwcontlev" ), "0 (Non quantificabile)", IF(str(?value) = "1" && (?paridentifier = "pest_swcontlev" || ?paridentifier = "pest_gwcontlev" ), "1 (Entro i limiti)", IF(str(?value) = "2" && (?paridentifier = "pest_swcontlev" || ?paridentifier = "pest_gwcontlev" ), "2 (Superiore ai limiti)", str(?value)))) AS ?valore)
}
ORDER BY ?URIpiattaforma ?paridentifier

[esegui query] – Livelli di contaminazione delle sostanze nelle acque superficiali della provincia di Pesaro-Urbino

PREFIX ispra-top: <https://w3id.org/italia/env/onto/top/>
PREFIX ispra-plc: <https://w3id.org/italia/env/onto/place/>
PREFIX ispra-emf: <https://w3id.org/italia/env/onto/inspire-mf/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>

SELECT distinct 
?syear AS ?anno 
str(?regdesc) AS ?regione 
str(?provdesc) AS ?provincia 
str(?mundesc) AS ?comune 
?platformtype AS ?tipopiattaforma
?platformidentifier AS ?piattaforma  
?long 
?lat  
?URIpiattaforma
?cas 
str(?substdesc) AS ?sostanza 
?descvalue AS ?descvalore
WHERE 
{
##PER ACQUE SOTTERRANEE SOSTITUIRE NELLA RIGA SOTTO swcontlevs CON gwcontlevs
?p ispra-top:hasBroader <https://w3id.org/italia/env/ld/pest/parameter/swcontlevs> . 
#hasBroader --> swcontlevs: only parameters (with substances) concerning the contamination level of the substance in the station

##TOGLIERE "#" DALLA RIGA SOTTO SE SI DESIDERA SELEZIONARE ES. SUPERIORI AI LIMITI ("2") E IMPOSTARE EVENTUALMENTE ALTRI VALORI ("0" O "1")
#?vv ispra-top:value "2" . # "0" = non-quantifiable; "1" = within the limits; "2" = over the limits
##TOGLIERE "#" DALLA RIGA SOTTO SE SI DESIDERA SELEZIONARE PER CODICE COMUNE (ES. "041005" O IMPOSTARE UN ALTRO CODICE)
#?mun ispra-plc:istat "041005"^^xsd:string .
##IMPOSTARE DALLA RIGA SOTTO SE SI DESIDERA SELEZIONARE PER CODICE PROVINCIA (SE NO ANTEPORRE "#") (ES. "021" o "022" PER LE PROVINCE DI "Bolzano" o "Trento") ANTEPONENDO  "#" ALLA RIGA SOPRA
?prov ispra-plc:istat "041"^^xsd:string .
## IMPOSTARE CODICE REGIONE: ES. "11" = region code "Marche"
FILTER(?regioncode = "11")
##TOGLIERE "#" DALLA RIGA SOTTO SE SI DESIDERA SELEZIONARE PER CODICE SOSTANZA (ES. "330-54-1" O IMPOSTARE UN ALTRO CODICE)
#FILTER(?cas = "330-54-1")
## SOSTITUIRE NELLA RIGA SOTTO L'ANNO (2018) CON QUELLO DESIDERATO
?indicator ispra-top:atTime <https://w3id.org/italia/env/ld/common/year/2018> .
## SOSTITUIRE NELLA RIGA SOTTO L'ANNO (2018) CON QUELLO DESIDERATO
GRAPH <https://w3id.org/italia/env/ld/pest/2018/> {
?indicator ispra-top:isMemberOf ?icc;
  ispra-top:atTime ?year;
  ispra-top:hasSource ?samplingseries;
  ispra-top:hasValue ?vv.
?vv ispra-top:hasUnitOfMeasure ?um;
  ispra-top:value ?value .
?samplingseries ispra-plc:hasFeature ?geofeature .
?geofeature geo:lat ?lat;
    geo:long ?long .
} 
GRAPH <https://w3id.org/italia/env/ld/pest/> {  
?p a ispra-top:Parameter;
  ispra-top:parametrises ?subst. #only parameters with substances
?icc ispra-top:isParametrisedBy ?p;
  ispra-top:isPartOf ?ic .
?ic ispra-top:isPartOf ?c.
?c ispra-top:isPartOf <https://w3id.org/italia/env/ld/pest/dataset> ;
  ispra-top:isCollectionOf ?mun .
}
?subst a  ispra-emf:FeatureOfInterest;
  rdfs:label ?substdesc .
?mun a ispra-plc:Municipality;
  rdfs:label ?mundesc;
  ispra-plc:istat ?lau_com;
  ispra-plc:hasDirectHigherRank ?prov ;
  ispra-plc:hasRegion ?reg .
?prov rdfs:label ?provdesc .
?reg rdfs:label ?regdesc.

BIND(SUBSTR(str(?indicator), 53, 2) AS ?regioncode)
BIND(SUBSTR(str(?indicator), 55, 2) AS ?platformtype)
BIND(SUBSTR(str(?year), 44, 4) AS ?syear)
BIND(REPLACE(SUBSTR(str(?p), 58), "_", "-", "i") AS ?cas)
BIND(IF(str(?value) = "0", "Non quantificabile", IF(str(?value) = "1", "Entro i limiti", IF(str(?value) = "2", "Superiore ai limiti","xxx"))) AS ?descvalue) 
BIND(CONCAT(SUBSTR(str(?geofeature), 52, STRLEN(str(?geofeature)) - 56), "_", ?syear) AS ?platformidentifier)
BIND(URI(CONCAT("https://w3id.org/italia/env/ld/pest/platform/00106_", ?platformidentifier)) AS ?URIpiattaforma)
FILTER (langMatches(lang(?mundesc),"it"))
FILTER (langMatches(lang(?substdesc),"it"))
} 
ORDER BY ?regdesc ?provdesc ?mundesc ?substdesc