Thesauri

Linked ISPRA fa un ampio uso di thesauri e vocabolari controllati utilizzati dai vari dipartimenti per classificare le risorse. In questa sezione è possibile scaricarli utilizzando la query SPARQL predefinita.

Vocabolari acque di balneazione

  • Vocabolario dei tipi di zona acque di balneazione
    IRI: https://w3id.org/italia/env/vocab/bathing_waters/bodies
    download
  • Vocabolario dello stato della qualità delle acque di balneazione
    IRI: https://w3id.org/italia/env/vocab/bathing_waters/quality
    download

 
Vocabolari per la Rete ondametrica e mareografia

  • Vocabolario livello di validazione dei dati della rete ondametrica nazionale
    IRI: https://w3id.org/italia/env/vocab/observations/certainty
    download
  • Vocabolario delle tipologie di stazioni di misura
    IRI: https://w3id.org/italia/env/vocab/platforms/datastation_types
    download
  • Vocabolario dello stato operativo
    IRI: https://w3id.org/italia/env/vocab/platforms/operational_status
    download

 
Vocabolari per la classificazione dei dissesti e delle opere di difesa del suolo – banca dati rendis

  • Vocabolario delle tipologie di dissesto
    IRI: https://w3id.org/italia/env/ld/skos/ihi/instabilitytype/vocabolario
    download
  • Vocabolario delle tipologie di litologia
    IRI: https://w3id.org/italia/env/ld/skos/ihi/lithologytype/vocabolario
    download
  • Vocabolario delle tipologie di Iter
    IRI: https://w3id.org/italia/env/ld/skos/ihi/itertype/vocabolario
    download
  • Vocabolario dei passi dell’Iter
    IRI: https://w3id.org/italia/env/ld/skos/ihi/steptype/vocabolario
    download
  • Vocabolario per le tipologie di opere
    IRI: https://w3id.org/italia/env/ld/skos/ihi/repairtype/vocabolario
    download
  • Vocabolario indicatori economici del dissesto
    IRI: https://w3id.org/italia/env/ld/skos/ihi/vocabolario
    download

 
Vocabolario per la classificazione degli indicatori del consumo del suolo

  • Vocabolario indicatori consumo suolo
    IRI: https://w3id.org/italia/env/vocab/land-take/indicators
    download

Esempi di Query

Per la generazione dei file di download è stata eseguita la seguente query sull’EndPoint SPARQL (sostituire IRI_DEL_THESAURO con la relativa IRI)

CONSTRUCT {?s ?p ?o}
WHERE {
 {?s ?p ?o . FILTER(?s = <IRI_DEL_THESAURO>)}
 UNION
 {?s ?p ?o . ?s <http://www.w3.org/2004/02/skos/core#inScheme> <IRI_DEL_THESAURO>}
}

Per la creazione del Vocabolario indicatori del consumo del suolo è stata utilizzata la seguente query sull’EndPoint SPARQL

PREFIX ispra-top: <https://w3id.org/italia/env/onto/top/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX dcatapit: <http://dati.gov.it/onto/dcatapit#>
PREFIX adms: <http://www.w3.org/ns/adms#>
PREFIX dcat: <http://www.w3.org/ns/dcat#>
PREFIX xkos: <http://rdf-vocabulary.ddialliance.org/xkos#>
PREFIX ndc: <https://w3id.org/italia/onto/NDC/>

CONSTRUCT {
<https://w3id.org/italia/env/vocab/land-take/indicators> a skos:ConceptScheme, dcatapit:Dataset, adms:Asset, dcat:Dataset ;
  dcterms:title "Vocabolario degli indicatori di consumo suolo"@it, "Vocabulary of land take indicators"@en ;
  rdfs:label "Vocabolario degli indicatori di consumo suolo"@it, "Vocabulary of land take indicators"@en ;
  dcterms:description "Vocabolario degli indicatori di consumo suolo (es. Percentuale di suolo consumato, Superficie di suolo non consumato in aree a pericolosità idraulica, ...)"@it, "Vocabulary of land take indicators (e.g. Land take in %, Land take in flood hazard zones, ...)"@en ;
  rdfs:comment "Vocabolario degli indicatori di consumo suolo (es. Percentuale di suolo consumato, Superficie di suolo non consumato in aree a pericolosità idraulica, ...)"@it, "Vocabulary of land take indicators (e.g. Land take in %, Land take in flood hazard zones, ...)"@en ;
  dcterms:language <http://publications.europa.eu/resource/authority/language/ITA>, <http://publications.europa.eu/resource/authority/language/ENG> ;
  dcterms:issued "2023-03-03"^^xsd:date ;
  dcterms:modified "2025-03-10"^^xsd:date ;
  dcterms:accrualPeriodicity <http://publications.europa.eu/resource/authority/frequency/IRREG> ;
  dcterms:identifier "https://w3id.org/italia/env/vocab/land-take/indicators" ;
  dcterms:creator <https://w3id.org/italia/env/ld/common/organisation/001> ;
  dcterms:publisher <https://w3id.org/italia/env/ld/common/organisation/001> ;
  dcterms:rightsHolder <https://w3id.org/italia/env/ld/common/organisation/001> ;
  owl:versionInfo "Version 0.2 - updated in March 2025 - Vocabolary metadata inserted."@en ,
                  "Versione 0.2 - aggiornata a marzo 2025 - Inseriti i metadati del vocabolario."@it ;
  dcterms:type <http://purl.org/adms/assettype/Taxonomy> ;
  xkos:numberOfLevels "2" ;
  ndc:keyConcept "indicators" ;
  dcterms:conformsTo  <https://w3id.org/italia/data/standard/SKOS> ;
  dcat:contactPoint <https://w3id.org/italia/env/ld/common/organization/001-LD> ;
  skos:hasTopConcept ?broader2 ;
  adms:representationTechnique <http://purl.org/adms/representationtechnique/SKOS> ;
  ##dcat:distribution <https://w3id.org/italia/env/ld/common/distribution/lt-indicators-RDF-TURTLE>, <https://w3id.org/italia/env/ld/common/distribution/lt-indicators-CSV> ;
  dcat:keyword "Land Take"@en , "Land"@en , "Land Use"@en , "Land consumption"@en ,
               "Consumo del suolo"@it , "Suolo"@it , "Suolo consumato "@it , "Uso del suolo"@it ;
  dcterms:subject <http://eurovoc.europa.eu/4630> ;
  dcat:theme <http://publications.europa.eu/resource/authority/data-theme/ENVI> .

## Indicatori
?s2 a skos:Concept;
  skos:inScheme <https://w3id.org/italia/env/vocab/land-take/indicators> ;
  dcterms:identifier ?id;
  skos:broader ?broader2;
  skos:prefLabel ?label;
  skos:exactMatch ?s;
  skos:definition ?description .
}
WHERE {
?s  a ispra-top:Parameter;
  ispra-top:identifier ?identifier;
  rdfs:label ?label .
OPTIONAL { ?s   dcterms:description ?description . }
OPTIONAL { ?s ispra-top:hasBroader ?broader . }
FILTER(SUBSTR(str(?identifier), 1, 5) = "soilc")
FILTER(?s != <https://w3id.org/italia/env/ld/soilc/parameter/cod_reg>)
FILTER(?s != <https://w3id.org/italia/env/ld/soilc/parameter/nome_provincia>)
FILTER(?s != <https://w3id.org/italia/env/ld/soilc/parameter/nome_regione>)
FILTER(?s != <https://w3id.org/italia/env/ld/soilc/parameter/pro_com>)
FILTER(?s != <https://w3id.org/italia/env/ld/soilc/parameter/nome_comune>)
FILTER(?s != <https://w3id.org/italia/env/ld/soilc/parameter/cod_pro>)
BIND(SUBSTR(?identifier, 7) AS ?id)
BIND(URI(REPLACE(REPLACE(REPLACE(str(?s), "soilc", "land-take"), "parameter", "indicators"), "ld", "vocab")) AS ?s2)
BIND(URI(REPLACE(REPLACE(REPLACE(str(?broader), "soilc", "land-take"), "parameter", "indicators"), "ld", "vocab")) AS ?broader2)
}