Pesticides

Pesticides in Italy

Pesticides are chemicals used to control weeds, insects and other pests in agricultural areas, and a variety of other land-use settings. Pesticides can be distinguished, from a regulatory point of view, among substances used in plant protection products and in biocidal products, which are used in various fields (disinfectants, wood preservatives, pesticides for non agricultural use, antifouling, etc.).

The Regions and Autonomous Provinces carry out monitoring within the framework of the survey programmes provided for by Legislative Decree No. 152 of 3 April 2006 [D. Lgs. 152/2006], transmit the results to ISPRA, which processes and evaluates them. ISPRA provides the technical-scientific guidelines for the programming of monitoring. Moreover, the Institute feeds some of the indicators provided for by the National Action Plan for the sustainable use of plant protection products (NAP), established by the decree of 15 July 2015 [DM 172/2015].

The levels of contamination are compared with the regulatory limits for surface water and for groundwater. Environmental Quality Standards (EQS), set for surface water in the contest of the WFD, are concentrations of pollutants or group of pollutants in water, sediment or biota which should not be exceeded in order to protect human health and the environment. The derivation of EQS is based on the knowledge of the levels of acute and chronic toxicity of the species representative of three trophic levels of the aquatic environment.

The Directive 2006/118/EC on the protection of groundwater, sets standards of environmental quality, defined as the concentrations which should not be exceeded in order to protect the human health and the environment.

For further details:

Pesticides Portal

National report on pesticides in waters

WHAT DOES IT INCLUDE?

• The register of monitoring stations and contamination levels obtained by comparison with legal limits (Environmental Quality Standards, EQS).
• For each monitoring point, it is possible to consult geographical information, contamination level, pesticides searched and found, and statistical data on monitoring.

EXAMPLE OF QUERY

[execute query] – Surface water stations in the Marche region year 2018 with contamination levels above the limits

PREFIX ispra-top: <https://w3id.org/italia/env/onto/top/>
PREFIX ispra-plc: <https://w3id.org/italia/env/onto/place/>
PREFIX ispra-emf: <https://w3id.org/italia/env/onto/inspire-mf/>

SELECT DISTINCT 
str(?geoyear) AS ?year
str(?admincode) AS ?admin_code
str(?codereg) AS ?reg_code
str(?regdesc) AS ?region
str(?codeprov) AS ?prov_code
str(?provdesc) AS ?province
str(?mundesc) AS ?municipality 
?platformtype AS ?platform_type 
?long 
?lat 
?URIplatform
?par AS ?URIparameter 
str(?parlabel) AS ?parameter 
?descvalue AS ?desc_value
WHERE
{
## SET REGION CODE: E.G. "11" = region code "Marche".
FILTER(str(?codereg)  = "11")
##REMOVE "#" FROM THE RIGHT BELOW IF YOU WANT TO SELECT BY PROVINCE CODE (e.g. "021" or "022" FOR THE PROVINCES OF "Bolzano" or "Trento") BY PREVIOUSLY ADDING "#" TO THE LINE ABOVE
#FILTER(str(?codeprov)  = "021")

##FOR GROUND WATER REPLACE IN THE LINE BELOW pest_swcontlev WITH pest_gwcontlev
?par ispra-top:identifier "pest_swcontlev" .
##FOR GROUND WATER REPLACE IN THE LINE BELOW sw WITH gw
FILTER(?platformtype= "sw")
## REPLACE IN THE LINE BELOW THE YEAR (2018) WITH THE DESIRED YEAR
?time ispra-top:year "2018"^^xsd:gYear .
##REMOVE '#' FROM THE LINE BELOW IF YOU WISH TO SELECT BY MUNICIPALITY CODE (E.G. '041033' OR SET ANOTHER CODE)
#?mun ispra-plc:istat "041033"^^xsd:string .
## REPLACE IN THE LINE BELOW THE YEAR (2018) WITH THE DESIRED YEAR
?indicator ispra-top:hasSource /  ispra-plc:hasFeature ?geofeature ;
  ispra-top:isMemberOf ?icc;
  ispra-top:hasValue / ispra-top:value ?value .
?samplingseries a ispra-emf:SamplingSeries;
   ispra-plc:hasFeature ?geofeature .
?geofeature ispra-top:atTime ?time;
   geo:lat ?lat;
   geo:long ?long .
?c ispra-top:isPartOf <https://w3id.org/italia/env/ld/pest/dataset>;
  ispra-top:isCollectionOf ?mun .
?ic a ispra-emf:IndicatorCollection;
  ispra-top:isPartOf ?c.
?icc ispra-top:isPartOf ?ic;
  ispra-top:isParametrisedBy ?par .
?par rdfs:label ?parlabel .
?mun a ispra-plc:Municipality;
  rdfs:label ?mundesc;
  ispra-plc:istat ?lau_com;
  ispra-plc:hasDirectHigherRank ?prov ;
  ispra-plc:hasRegion ?reg .
?prov rdfs:label ?provdesc .
?prov ispra-plc:istat ?codeprov .
?reg rdfs:label ?regdesc.
?reg ispra-plc:istat ?codereg .
?time ispra-top:year ?geoyear .

BIND(IF(str(?value) = "0", "Not quantifiable", IF(str(?value) = "1", "Within the limits", IF(str(?value) = "2", "Over the limits","xxx"))) AS ?descvalue) 
BIND(SUBSTR(str(?geofeature), 52, STRLEN(str(?geofeature)) - 56) AS ?platformidentifier)
BIND(SUBSTR(?platformidentifier, 1, 2) AS ?admincode)
BIND(SUBSTR(?platformidentifier, 3, 2) AS ?platformtype)
BIND(URI(CONCAT("https://w3id.org/italia/env/ld/pest/platform/00106_", ?platformidentifier, "_", str(?geoyear))) AS ?URIplatform)
#FILTER(?admincode  = "11")
FILTER (langMatches(lang(?mundesc),"it"))
FILTER (langMatches(lang(?parlabel),"en"))
}
ORDER BY ?regdesc ?provdesc ?mundesc ?descvalue

[execute query] – Groundwater stations in the Marche region year 2018 with contamination level, substances searched for, substances found, etc.

PREFIX ispra-top: <https://w3id.org/italia/env/onto/top/>
PREFIX ispra-plc: <https://w3id.org/italia/env/onto/place/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>

SELECT DISTINCT 
str(?geoyear) AS ?year 
str(?regdesc) AS ?region 
str(?provdesc) AS ?province 
str(?mundesc) AS ?municipality 
str(?lblbasin) AS ?basin_desc 
?platformtype AS ?platform_type 
?platformidentifier AS ?platform_id 
?lat 
?long 
?paridentifier AS ?par_code  
str(?parlabel) AS ?parameter 
?value_ 
#str(?umdesc) AS ?unitadimisura 
?URIplatform
?par AS ?URIparameter 
?indicator AS ?URIindicator
WHERE
{
##REMOVE '#' FROM THE LINE BELOW IF YOU WISH TO SELECT BY REGION CODE: E.G. "11" = region code "Marche
FILTER(str(?codereg)  = "11")
##REMOVE "#" FROM THE RIGHT BELOW IF YOU WANT TO SELECT BY PROVINCE CODE (e.g. "021" or "022" FOR THE PROVINCES OF "Bolzano" or "Trento") BY PREVIOUSLY ADDING "#" TO THE LINE ABOVE
#FILTER(str(?codeprov)  = "021")

##FOR SUPERFICIAL WATER REPLACE IN THE ROW BELOW gw WITH sw
FILTER(?platformtype = "gw")

##REMOVE '#' FROM THE LINE BELOW IF YOU WISH TO SELECT BY MUNICIPALITY CODE (E.G. '041033' OR SET ANOTHER CODE)
#?mun ispra-plc:istat "041033"^^xsd:string .

## REPLACE IN THE LINE BELOW THE YEAR (2018) WITH THE DESIRED YEAR
?time ispra-top:year "2018"^^xsd:gYear .
## REPLACE IN THE LINE BELOW THE YEAR (2018) WITH THE DESIRED YEAR
?indicator ispra-top:hasSource / ispra-plc:hasFeature ?geofeature ;
  ispra-top:isMemberOf ?icc;
  ispra-top:hasValue / ispra-top:value ?value .
#ispra-top:hasUnitOfMeasure ?um. 
?samplingseries ispra-plc:hasFeature ?geofeature .
?geofeature ispra-top:atTime ?time;
    geo:lat ?lat;
    geo:long ?long;
    ispra-top:isPartOf ?basin . 
##FOR SUPERFICIAL WATER REPLACE IN THE ROW BELOW pest_ggw WITH pest_gsw
?parbroader ispra-top:identifier "pest_ggw" .

?c  ispra-top:isPartOf <https://w3id.org/italia/env/ld/pest/dataset>;
  ispra-top:isCollectionOf ?mun .
?ic  ispra-top:isPartOf ?c.
?icc  ispra-top:isPartOf ?ic;
  ispra-top:isParametrisedBy ?par .
?par rdfs:label ?parlabel;
  ispra-top:identifier ?paridentifier;
  ispra-top:hasBroader ?parbroader .
#?um rdfs:label ?umdesc . 
?mun  rdfs:label ?mundesc;
  ispra-plc:istat ?lau_com;
  ispra-plc:hasDirectHigherRank ?prov ;
  ispra-plc:hasRegion ?reg .
?prov rdfs:label ?provdesc .
?prov ispra-plc:istat ?codeprov . 
?reg rdfs:label ?regdesc.
?reg ispra-plc:istat ?codereg .
#?codereg bif:contains "'11'". 
#FILTER ( isLiteral(?codereg ) ) .
?time ispra-top:year ?geoyear .
?basin rdfs:label ?lblbasin .

FILTER (langMatches(lang(?mundesc),"it"))
FILTER (langMatches(lang(?parlabel),"en"))
#FILTER(lang(?umdesc)='en')
FILTER(lang(?lblbasin)='en')
BIND(SUBSTR(str(?geofeature), 52, STRLEN(str(?geofeature)) - 56) AS ?platformidentifier)
BIND(SUBSTR(?platformidentifier, 1, 2) AS ?admincode) 
BIND(SUBSTR(?platformidentifier, 3, 2) AS ?platformtype)
BIND(URI(CONCAT("https://w3id.org/italia/env/ld/pest/platform/00106_", ?platformidentifier, "_", str(?geoyear))) AS ?URIplatform)
BIND(IF(str(?value) = "0" && (?paridentifier = "pest_swcontlev" || ?paridentifier = "pest_gwcontlev" ), "0 (Not quantifiable)", IF(str(?value) = "1" && (?paridentifier = "pest_swcontlev" || ?paridentifier = "pest_gwcontlev" ), "1 (Within the limits)", IF(str(?value) = "2" && (?paridentifier = "pest_swcontlev" || ?paridentifier = "pest_gwcontlev" ), "2 (Over the limits)", str(?value)))) AS ?value_) 
}
ORDER BY ?URIplatform ?paridentifier

[execute query] – Contamination levels of substances in surface waters in the Pesaro-Urbino province

PREFIX ispra-top: <https://w3id.org/italia/env/onto/top/>
PREFIX ispra-plc: <https://w3id.org/italia/env/onto/place/>
PREFIX ispra-emf: <https://w3id.org/italia/env/onto/inspire-mf/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>

SELECT distinct 
?syear AS ?year 
str(?regdesc) AS ?region 
str(?provdesc) AS ?province 
str(?mundesc) AS ?municipality 
?platformtype AS ?platform_type
?platformidentifier AS ?platform_id  
?long 
?lat  
?URIplatform
?cas 
str(?substdesc) AS ?substance 
?descvalue AS ?desc_value
WHERE 
{
##FOR GROUND WATER REPLACE IN THE ROW BELOW swcontlevs WITH gwcontlevs
?p ispra-top:hasBroader <https://w3id.org/italia/env/ld/pest/parameter/swcontlevs> . 
#hasBroader --> swcontlevs: only parameters (with substances) concerning the contamination level of the substance in the station

##REMOVE '#' FROM THE LINE BELOW IF YOU WISH TO SELECT EX. HIGHER THAN THE LIMITS ("2") AND POSSIBLY SET OTHER VALUES ("0" OR "1")
#?vv ispra-top:value "2" . # "0" = non-quantifiable; "1" = within the limits; "2" = over the limits
##REMOVE '#' FROM THE LINE BELOW IF YOU WISH TO SELECT BY MUNICIPALITY CODE (E.G. '041005' OR SET ANOTHER CODE)
#?mun ispra-plc:istat "041005"^^xsd:string .
##SET FROM THE RIGHT BELOW IF YOU WANT TO SELECT BY PROVINCE CODE (IF NOT, PREVIOUSLY "#") (e.g. "021" or "022" FOR THE PROVINCES OF "Bolzano" or "Trento") BY PREVIOUSLY "#" TO THE LINE ABOVE
?prov ispra-plc:istat "041"^^xsd:string .
## SET REGION CODE: E.G. "11" = region code "Marche".
FILTER(?regioncode = "11")
##REMOVE "#" FROM THE LINE BELOW IF YOU WISH TO SELECT BY SUBSTANCE CODE (E.G. "330-54-1" OR SET ANOTHER CODE)
#FILTER(?cas = "330-54-1")
## REPLACE IN THE LINE BELOW THE YEAR (2018) WITH THE DESIRED YEAR
?indicator ispra-top:atTime <https://w3id.org/italia/env/ld/common/year/2018> .
## REPLACE IN THE LINE BELOW THE YEAR (2018) WITH THE DESIRED YEAR
GRAPH <https://w3id.org/italia/env/ld/pest/2018/> {
?indicator ispra-top:isMemberOf ?icc;
  ispra-top:atTime ?year_;
  ispra-top:hasSource ?samplingseries;
  ispra-top:hasValue ?vv.
?vv ispra-top:hasUnitOfMeasure ?um;
  ispra-top:value ?value .
?samplingseries ispra-plc:hasFeature ?geofeature .
?geofeature geo:lat ?lat;
    geo:long ?long .
} 
GRAPH <https://w3id.org/italia/env/ld/pest/> {  
?p a ispra-top:Parameter;
  ispra-top:parametrises ?subst. #only parameters with substances
?icc ispra-top:isParametrisedBy ?p;
  ispra-top:isPartOf ?ic .
?ic ispra-top:isPartOf ?c.
?c ispra-top:isPartOf <https://w3id.org/italia/env/ld/pest/dataset> ;
  ispra-top:isCollectionOf ?mun .
}
?subst a  ispra-emf:FeatureOfInterest;
  rdfs:label ?substdesc .
?mun a ispra-plc:Municipality;
  rdfs:label ?mundesc;
  ispra-plc:istat ?lau_com;
  ispra-plc:hasDirectHigherRank ?prov ;
  ispra-plc:hasRegion ?reg .
?prov rdfs:label ?provdesc .
?reg rdfs:label ?regdesc.

BIND(SUBSTR(str(?indicator), 53, 2) AS ?regioncode)
BIND(SUBSTR(str(?indicator), 55, 2) AS ?platformtype)
BIND(SUBSTR(str(?year_), 44, 4) AS ?syear)
BIND(REPLACE(SUBSTR(str(?p), 58), "_", "-", "i") AS ?cas)
BIND(IF(str(?value) = "0", "Not quantifiable", IF(str(?value) = "1", "Within the limits", IF(str(?value) = "2", "Over the limits","xxx"))) AS ?descvalue) 
BIND(CONCAT(SUBSTR(str(?geofeature), 52, STRLEN(str(?geofeature)) - 56), "_", ?syear) AS ?platformidentifier)
BIND(URI(CONCAT("https://w3id.org/italia/env/ld/pest/platform/00106_", ?platformidentifier)) AS ?URIplatform)
FILTER (langMatches(lang(?mundesc),"it"))
FILTER (langMatches(lang(?substdesc),"en"))
} 
ORDER BY ?regdesc ?provdesc ?mundesc ?substdesc